module discord.api.util;

import std.uri,
       std.array,
       std.format,
       std.algorithm.iteration;
import vibe.http.client,
       vibe.stream.operations;
import discord.types,
       discord.util.errors;

/**
  Represents an error from the Discord API.
*/
class APIError : BaseError {
  this(int code, string msg) {
    super("[%s] %s", code, msg);
  }
}

/**
  URL constructor to build routes
*/
struct U {
  private {
    string          _bucket;
    string[]        paths;
    string[string]  params;
  }

  @property string value() {
    string url = this.paths.join("/");

    if (this.params.length) {
      string[] parts;
      foreach (ref key, ref value; this.params) {
        parts ~= format("%s=%s", key, encodeComponent(value));
      }
      url ~= "?" ~ parts.join("&");
    }
    return "/" ~ url;
  }
  this(string url) {
    this.paths ~= url;
  }
  this(string paramKey, string paramValue) {
    this.params[paramKey] = paramValue;
  }
  string getBucket() {
    return this._bucket;
  }
  U opCall(string url) {
    this.paths ~= url;
    return this;
  }
  U opCall(Snowflake s) {
    this.paths ~= s.toString();
    return this;
  }
  U opCall(string paramKey, string paramValue) {
    this.params[paramKey] = paramValue;
    return this;
  }
  U bucket(string bucket) {
    this._bucket = bucket;
    return this;
  }
  U param(string name, string value) {
    this.params[name] = value;
    return this;
  }
}

/**
  Represents an error response from Discord API.
*/
class APIResponse {
  private {
    HTTPClientResponse res;
  }
  string content;
  this(HTTPClientResponse res) {
    this.res = res;
    this.content = res.bodyReader.readAllUTF8();
    this.res.disconnect();
  }

  APIResponse ok() {
    if (100 < this.statusCode && this.statusCode < 400) {
      return this;
    }
    throw new APIError(this.statusCode, this.content);
  }

  @property string contentType() {
    return this.res.contentType;
  }

  @property int statusCode() {
    return this.res.statusCode;
  }

  @property VibeJSON vibeJSON() {
    return parseJsonString(this.content);
  }

  string header(string name, string def="") {
    if (name in this.res.headers) {
      return this.res.headers[name];
    }
    return def;
  }
}